Lingo Dictionary > T-Z > xtraList |  |

xtraList

Syntax

    the xtraList

Description

System property; displays a linear property list of all available Xtras and their file versions. This property is useful when the functionality of a movie depends on a certain version of an Xtra.

#name | Specifies the file name of the Xtra on the current platform. It is possible to have a list without a `#name` entry, such as when the Xtra exists only on one platform.
#version | Specifies the same version number that appears in the Properties dialog box (Windows) or Info window (Macintosh) when the file is selected on the desktop. An Xtra may not necessarily have a version number.

There are two possible properties that can appear in `XtraList`:

Example

This statement displays the `xtraList` in the Message window:

    put the xtraList

Example

This handler checks the version of a given Xtra:

    -- This handler checks all the available Xtras to return the version of the requested Xtra
    -- The XtraFileName may be only a partial match if desired
    -- Use the full file name for more exact usage
    -- The string returned is either the version property for the Xtra or an empty string
    -- It may be empty if either the version property doesn't exist or the Xtra is not found in the available list
    on GetXtraVersion XtraFileName
      --  Get the entire list of Xtras and their information
    	listOfXtras = the xtraList
      --  Initialize the local variable to contain the version
    	theVersion = ""
      --  Iterate through all the Xtras listed
    	repeat with currentXtra in listOfXtras
        --    If the current Xtra's name contains the Xtra passed in, then check for the version
    		if currentXtra.name contains XtraFileName then
          --      First determine if the version property exists for that Xtra
    			versionFlag = getaProp(currentXtra, #version)
          --      If the version property is not VOID, then set the local variable to	--	 the string contained in that property value
    			if not voidP(versionFlag) then
    				theVersion = currentXtra.version
    			end if
    		end if
    	end repeat
    --  Return the version information found or an empty string
    	return theVersion
    end

See also

`movieXtraList`, `getaProp`